|
Server : Apache/2.2.17 (Unix) mod_ssl/2.2.17 OpenSSL/0.9.8e-fips-rhel5 DAV/2 PHP/5.2.17 System : Linux localhost 2.6.18-419.el5 #1 SMP Fri Feb 24 22:47:42 UTC 2017 x86_64 User : nobody ( 99) PHP Version : 5.2.17 Disable Function : NONE Directory : /home/queenjbs/www/FusionChart/Code/ASP/DB_JS/ |
Upload File : |
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<%@ Language=VBScript %>
<html>
<head>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<link href="../assets/ui/css/style.css" rel="stylesheet" type="text/css" />
<title>
FusionCharts - Database + JavaScript Example
</title>
<%
'We've included ../Includes/FusionCharts.asp, which contains functions
'to help us easily embed the charts.
%>
<!-- #INCLUDE FILE="../Includes/FusionCharts.asp" -->
<!-- #INCLUDE FILE="../Includes/DBConn.asp" -->
<%
'In this example, we show a combination of database + JavaScript rendering using FusionCharts.
'The entire app (page) can be summarized as under. This app shows the break-down
'of factory wise output generated. In a pie chart, we first show the sum of quantity
'generated by each factory. These pie slices, when clicked would show detailed date-wise
'output of that factory.
'The XML data for the pie chart is fully created in ASP at run-time. ASP interacts
'with the database and creates the XML for this.
'Now, for the column chart (date-wise output report), we do not submit request to the server.
'Instead we store the data for the factories in JavaScript arrays. These JavaScript
'arrays are rendered by our ASP Code (at run-time). We also have a few defined JavaScript
'functions which react to the click event of pie slice.
'We've used an Access database which is present in ../DB/FactoryDB.mdb.
'It just contains two tables, which are linked to each other.
'Before the page is rendered, we need to connect to the database and get the
'data, as we'll need to convert this data into JavaScript variables.
'The following string will contain the JS Data and variables.
'This string will be built in ASP and rendered at run-time as JavaScript.
Dim jsVarString
jsVarString = ""
'Database Objects
Dim oRs, oRs2, strQuery, indexCount
indexCount = 0
'Create the recordset to retrieve data
Set oRs = Server.CreateObject("ADODB.Recordset")
'Iterate through each factory
strQuery = "select * from Factory_Master"
Set oRs = oConn.Execute(strQuery)
While not oRs.EOF
indexCount = indexCount + 1
'Create JavaScript code to add sub-array to data array
'data is an array defined in JavaScript (see below)
'We've added vbTab & vbCRLF to data so that if you View Source of the
'output HTML, it will appear properly. It helps during debugging
jsVarString = jsVarString & vbTab & vbTab & "data[" & indexCount & "] = new Array();" & vbCRLF
'Now create second recordset to get date-wise details for this factory
Set oRs2 = Server.CreateObject("ADODB.Recordset")
strQuery = "select * from Factory_Output where FactoryId=" & ors("FactoryId") & " order by DatePro Asc" & vbCRLF
Set oRs2 = oConn.Execute(strQuery)
While not oRs2.EOF
'Put this data into JavaScript as another nested array.
'Finally the array would look like data[factoryIndex][i][dataLabel,dataValue]
jsVarString = jsVarString & vbTab & vbTab & "data[" & indexCount & "].push(new Array('" & datePart("d",ors2("DatePro")) & "/" & datePart("m",ors2("DatePro")) & "'," & ors2("Quantity") & "));" & vbCRLF
oRs2.MoveNext()
Wend
'Close recordset
Set oRs2 = Nothing
oRs.MoveNext()
Wend
%>
<script LANGUAGE="Javascript" SRC="../../FusionCharts/FusionCharts.js">
</script>
<script LANGUAGE="JavaScript">
//Here, we use a mix of server side script (ASP) and JavaScript to
//render our data for factory chart in JavaScript variables. We'll later
//utilize this data to dynamically plot charts.
//All our data is stored in the data array. From ASP, we iterate through
//each recordset of data and then store it as nested arrays in this data array.
var data = new Array();
<%
'Write the data as JavaScript variables here
Response.Write(jsVarString)
'The data is now present as arrays in JavaScript. Local JavaScript functions
'can access it and make use of it. We'll see how to make use of it.
%>
/**
* updateChart method is invoked when the user clicks on a pie slice.
* In this method, we get the index of the factory, build the XML data
* for that that factory, using data stored in data array, and finally
* update the Column Chart.
* @param factoryIndex Sequential Index of the factory.
*/
function updateChart(factoryIndex){
//Storage for XML data document
var strXML = "<chart palette='2' caption='Factory " + factoryIndex + " Output ' subcaption='(In Units)' xAxisName='Date' showValues='1' labelStep='2' >";
//Add <set> elements
var i=0;
for (i=0; i<data[factoryIndex].length; i++){
strXML = strXML + "<set label='" + data[factoryIndex][i][0] + "' value='" + data[factoryIndex][i][1] + "' />";
}
//Closing Chart Element
strXML = strXML + "</chart>";
//Get reference to chart object using Dom ID "FactoryDetailed"
var chartObj = getChartFromId("FactoryDetailed");
//Update it's XML
chartObj.setDataXML(strXML);
}
</script>
<!--[if IE 6]>
<script type="text/javascript" src="../assets/ui/js/DD_belatedPNG_0.0.8a-min.js"></script>
<script>
/* select the element name, css selector, background etc */
DD_belatedPNG.fix('img');
/* string argument can be any CSS selector */
</script>
<![endif]-->
<style type="text/css">
h2.headline {
font: normal 110%/137.5% "Trebuchet MS", Arial, Helvetica, sans-serif;
padding: 0;
margin: 25px 0 25px 0;
color: #7d7c8b;
text-align: center;
}
p.small {
font: normal 68.75%/150% Verdana, Geneva, sans-serif;
color: #919191;
padding: 0;
margin: 0 auto;
width: 664px;
text-align: center;
}
</style>
</head>
<body>
<div id="wrapper">
<div id="header">
<div class="logo"><a class="imagelink" href="http://www.fusioncharts.com/" target="_blank"><img src="../assets/ui/images/fusionchartsv3.2-logo.png" width="131" height="75" alt="FusionCharts XT logo" /></a></div>
<h1 class="brand-name">FusionCharts XT</h1>
<h1 class="logo-text">FusionCharts Database + JavaScript Example</h1>
</div>
<div class="content-area">
<div id="content-area-inner-main">
<h2 class="headline">Inter-connected charts - Click on any pie slice to see detailed chart below</h2>
<div class="gen-chart-render">
<center>
<%
'Initialize the Pie chart with sum of production for each of the factories
'strXML will be used to store the entire XML document generated
Dim strXML
'Re-initialize Index
indexCount=0
'Generate the chart element
strXML = "<chart caption='Factory Output report' subCaption='By Quantity' pieSliceDepth='30' showBorder='1' formatNumberScale='0' numberSuffix=' Units' >"
'Move back to first index of the factory master recordset
oRs.MoveFirst()
While Not oRs.Eof
'Update index count - sequential
indexCount = indexCount + 1
'Now create second recordset to get details for this factory
Set oRs2 = Server.CreateObject("ADODB.Recordset")
strQuery = "select sum(Quantity) as TotOutput from Factory_Output where FactoryId=" & ors("FactoryId")
Set oRs2 = oConn.Execute(strQuery)
'Generate <set label='..' value='..' link='..' />
'Note that we're setting link as updateChart(factoryIndex) - JS Function
strXML = strXML & "<set label='" & ors("FactoryName") & "' value='" & ors2("TotOutput") & "' link='javaScript:updateChart(" & indexCount & ")'/>"
'Close recordset
Set oRs2 = Nothing
oRs.MoveNext
Wend
'Finally, close <chart> element
strXML = strXML & "</chart>"
Set oRs = nothing
'Create the chart - Pie 3D Chart with data from strXML
Call renderChart("../../FusionCharts/Pie3D.swf", "", strXML, "FactorySum", 500, 250, false, false)
%>
<br>
<%
'Column 2D Chart with changed "No data to display" message
'We initialize the chart with <chart></chart>
Call renderChart("../../FusionCharts/Column2D.swf?ChartNoDataText=Please select a factory from pie chart above to view detailed data.", "", "<chart></chart>", "FactoryDetailed", 600, 250, false, false)
%>
</center>
</div>
<div class="clear"></div>
<p> </p>
<p class="small"> The charts in this page have been dynamically generated using data contained in a database. We've NOT hard-coded the data in JavaScript</p>
<div class="underline-dull"></div>
</div>
</div>
<div id="footer">
<ul>
<li><a href="../index.html"><span>« Back to list of examples</span></a></li>
<li class="pipe">|</li>
<li><a href="../NoChart.html"><span>Unable to see the chart above?</span></a></li>
</ul>
</div>
</div>
</body>
</html>